Глава 13 - Сетевые протоколы

Руководство пользователя REBOL/Core
Основное содержание
Отправьте нам отзыв

Содержание:

1. Обзор

REBOL включает несколько встроенных основных протоколов интернет-сервисов. Эти протоколы легко использовать в ваших сценариях; они не требуют дополнительных библиотек или включаемых файлов, и многие полезные операции могут быть выполнены с помощью только одной строчки исходного кода.

Поддерживаются протоколы, перечисленные в Сетевые протоколы:

	DNS	Domain Name Service: Служба доменных имен: переводит имена компьютеров в адреса и адреса в имена.
	Finger	Получает информацию о пользователе из его профиля.
	Whois	Получает информацию о регистрации домена.
	Daytime	Сетевой протокол времени. Получает время с сервера.
	HTTP	Hypertext Transfer Protocol. Протокол передачи гипертекста. Используется для Интернета.
	SMTP	Simple Mail Transfer Protocol. Простой протокол передачи почты. Используется для отправки электронной почты.
	POP	Post Office Protocol. Почтовый протокол. Используется для получения электронной почты.
	FTP	File Transfer Protocol. Протокол передачи файлов. Обменивается файлами с сервером.
	NNTP	Network News Transfer Protocol. Протокол передачи сетевых новостей. Публикует или читает новости Usenet.
	TCP	Transmission Control Protocol. Протокол управления передачей. Базовый интернет-протокол.
	UDP	User Datagram Protocol. Протокол пользовательских датаграмм. Пакетный протокол.

Кроме того, вы можете создавать обработчики для других Интернет-протоколов или создавать свои собственные протоколы.

2. Основы работы с сетью REBOL

2.1 Режимы работы

Существует два основных режима работы сети: атомарный и портовый.

Атомарные сетевые операции - это операции, которые выполняются с помощью одной функции. Например, вы можете прочитать всю веб-страницу с помощью одного вызова функции чтения. Нет необходимости отдельно открывать соединение или настраивать чтение. Все это делается автоматически как часть чтения. Например, вы можете ввести:

print read http://www.rebol.com

Хост найден и открыт, его веб-страница перенесена, а соединение закрыто.

На основе портов режим работы один, который использует более традиционный программный подход. Он включает в себя открытие порта и выполнение с ним различных последовательных операций. Например, если вы хотите читать свою электронную почту с POP-сервера по одному сообщению за раз, вы должны использовать этот метод. Вот пример, который читает и отображает всю вашу электронную почту:

pop: open pop://user:pass@mail.example.com
forall pop [print first pop]
close pop

Атомарный метод работы проще, но он более ограничен. Метод на основе портов позволяет выполнять больше типов операций, но также требует более глубокого понимания работы в сети.

2.2 Указание сетевых ресурсов

REBOL предлагает два подхода к определению сетевых ресурсов: URL-адреса и спецификации портов.

Унифицированные указатели ресурсов (URL) используются в Интернете для идентификации сетевого ресурса, такого как веб-страница, FTP-сайт, адрес электронной почты, файл или другой ресурс или услуга. URL-адреса являются неотъемлемой частью работы REBOL, и они могут быть выражены непосредственно на языке.

Стандартное обозначение URL-адресов состоит из схемы (scheme), за которой следует спецификация:

scheme:specification

Схема часто представляет собой имя протокола, например HTTP, FTP, SMTP и POP; однако это не является обязательным требованием. Схема может быть любым именем, которое идентифицирует метод, используемый для доступа к ресурсу.

Формат спецификации схемы зависит от схемы; однако в большинстве схем используется общий формат для определения сетевых хостов, имен пользователей, паролей, номеров портов и путей к файлам. Вот несколько часто используемых форматов:

scheme://host

scheme://host:port

scheme://user@host

scheme://user:pass@host

scheme://user:pass@host:port

scheme://host/path

scheme://host:port/path

scheme://user@host/path

scheme://user:pass@host/path

scheme://user:pass@host:port/path

В Спецификации сетевых ресурсов перечислены поля, используемые в вышеуказанных форматах.

	scheme	Имя, используемое для идентификации типа ресурса, часто такое же, как протокол. Например, HTTP, FTP и POP.
	host	Сетевое имя или адрес машины. Например, www.rebol.com, cnn.com, 192.168.0.1.
	port	Номер порта на хост-машине для используемой схемы. Обычно для этого есть значение по умолчанию, поэтому в большинстве случаев это не требуется. Примеры: 21, 23, 80, 8000.
	user	Имя пользователя для доступа к ресурсу.
	pass	Пароль для проверки имени пользователя.
	path	Путь к файлу или другой способ обращения к ресурсу. Это зависит от схемы (scheme). Некоторые схемы включают шаблоны и аргументы сценария (например, CGI).

Другой способ идентифицировать ресурс - использовать спецификацию port (порт) REBOL . Фактически, когда используется URL-адрес, он автоматически преобразуется в спецификацию порта. Спецификация порта может принимать намного больше аргументов, чем URL-адрес, но для ее выражения требуется несколько строк.

Спецификация порта записывается как определение объектного блока, которое предоставляет все параметры, необходимые для доступа к сетевому ресурсу. Например, URL-адрес для доступа к веб-сайту:

read http://www.rebol.com/developer.html

но это также можно записать как:

read [
    scheme: 'HTTP
    host: "www.rebol.com"
    target: %/developer.html
]

URL-адрес для чтения FTP может быть:

read ftp://bill:vbs@ftp.example.com:8000/file.txt

но это также можно записать как:

read [
    scheme: 'FTP
    host: "ftp.example.com"
    port-id: 8000
    target: %/file.txt
    user: "bill"
    pass: "vbs"
]

Кроме того, есть много других полей порта, которые можно указать, например тайм-аут, тип доступа и безопасность.

2.3 Схемы, обработчики и протоколы

Сеть REBOL работает с использованием схем (schemes) для идентификации обработчиков (handlers), которые обмениваются данными с протоколами (protocols).

В REBOL схема (schemes) используется для идентификации метода доступа к ресурсу. Этот метод использует объект кода, который называется обработчиком (handlers). Каждая из схем URL-адресов, поддерживаемых REBOL (например, HTTP, FTP), имеет обработчик. Список схем можно получить с помощью:

probe next first system/schemes
[default Finger Whois Daytime SMTP POP HTTP FTP NNTP]

Кроме того, есть имена схем более низкого уровня, которые здесь не показаны. Например, схемы TCP и UDP используются для прямой связи более низкого уровня.

В этот список можно добавлять новые схемы. Например, вы можете определить свою собственную схему, называемую FTP2, которая предоставляет специальные функции для доступа по FTP, такие как автоматическое указание вашего имени пользователя и пароля, поэтому его не нужно включать в каждый URL-адрес FTP.

Большинство обработчиков используются для обеспечения интерфейса для сетевого протокола. Протокол (protocol) используется для обмена данными между различными устройствами, в том числе клиентов и серверов.

Несмотря на то, что каждый протокол очень отличается по способу взаимодействия, у него есть некоторые общие черты с другими протоколами. Например, для большинства протоколов требуется, чтобы сетевое соединение было открыто (opened), прочитано (read), записано (written) и закрыто (closed). Эти общие операции выполняются обработчиком по умолчанию в REBOL. Этот обработчик упрощает реализацию таких протоколов, как finger, whois и daytime.

Обработчики схем записываются как объекты. Обработчик по умолчанию служит корневым объектом для всех остальных обработчиков. Когда обработчику требуется определенное поле, например значение тайм-аута для чтения данных, если значение не определено в конкретном обработчике, оно будет предоставлено обработчиком по умолчанию. Следовательно, обработчики накладывают друг на друга свои поля и значения. Вы также можете создать обработчики, которые используют другие обработчики для значений по умолчанию. Например, вы можете создать обработчик FTP2, который сначала ищет отсутствующие поля в обработчике FTP, а затем в обработчике по умолчанию.

Когда порт используется для доступа к сетевым ресурсам, он связан с определенным обработчиком. Обработчик и порт вместе образуют единицу, которая используется для предоставления данных, кода и информации о состоянии для обработки всех протоколов.

Исходный код обработчиков можно получить из объекта system/scheme (система/схема). Это может быть полезно, если вы хотите изменить поведение обработчика или создать свой собственный обработчик. Например, чтобы просмотреть код обработчика whois, введите:

probe get in system/schemes 'whois

Обратите внимание, что вы видите составную часть обработчика по умолчанию и обработчика whois. Фактический исходный код, который используется для создания обработчика whois, состоит всего из нескольких строк:

make Root-Protocol [
    open-check:  [[any [port/user ""]] none]
    net-utils/net-install Whois make self [] 43
]

2.4 Обработчики мониторинга

В целях отладки вы можете отслеживать действия любого обработчика. У каждого обработчика есть свои собственные выходные данные отладки, чтобы указать, какие операции выполняются. Чтобы включить отладку сети, включите трассировку сети с помощью строки:

trace/net on

Чтобы отключить отладку сети, используйте:

trace/net off

Вот пример:

read pop://carl:poof@zen.example.com
URL Parse: carl poof zen.example.com none none none
Net-log: ["Opening tcp for" POP]
connecting to: zen.example.com
Net-log: [none "+OK"]
Net-log: {+OK QPOP (version 2.53) at zen.example.com starting.}
Net-log: [["USER" port/user] "+OK"]
Net-log: "+OK Password required for carl."
Net-log: [["PASS" port/pass] "+OK"]
** User Error: Server error: tcp -ERR Password supplied for "carl"
is incorrect.
** Where: read pop://carl:poof@zen.example.com

3. Начальная настройка

Сеть REBOL встроена. Для создания сценариев, использующих сетевые протоколы, вам не нужны специальные включаемые файлы или библиотеки. Единственное требование - предоставить основную информацию, необходимую для подключения протоколов к серверам или через брандмауэры и прокси. Например, для отправки электронной почты протоколу SMTP необходимо имя SMTP-сервера и адрес электронной почты для ответа.

3.1 Основные настройки сети

Когда вы запускаете REBOL в первый раз, вам будет предложено ввести необходимые сетевые настройки, которые хранятся в файле user.r. REBOL использует этот файл для загрузки необходимых сетевых настроек при каждом запуске. Если user.r не создан и REBOL не может найти существующий файл в своих путях, никакие настройки не загружаются. См. Главу «Эксплуатация» для получения дополнительной информации.

Чтобы изменить настройки сети, введите в командной строке set-user. Это запускает тот же сценарий конфигурации сети, который запускался при первом запуске REBOL. Этот скрипт загружается из файла user.r. Если этот файл не может быть найден или если вы хотите отредактировать настройку напрямую, вы можете использовать текстовый редактор для user.r.

В файле user.r настройки сети находятся в блоке, который следует за функцией set-net. Как минимум, блок должен содержать два элемента:

• Ваш адрес электронной почты для использования в полях отправителя и ответа в сообщениях электронной почты, а также для анонимного входа по FTP.
• Ваш сервер по умолчанию; это также ваш основной почтовый сервер.

Кроме того, вы можете указать еще несколько пунктов:

• Другой сервер входящей электронной почты (для POP)
• Прокси-сервер (для подключения к сети)
• Номер порта прокси
• Тип прокси (см. Настройки прокси ниже).

Вы также можете добавить строки после функции set-net для настройки других значений протокола. Например, вы можете установить значения тайм-аута для протоколов, установить пассивный режим FTP, установить идентификатор HTTP-агента пользователя, настроить отдельные прокси для разных протоколов и многое другое.

Пример set-net:

set-net [user@domain.dom mail.server.dom]

В первом поле указана ваша электронная почта с адреса, а во втором поле указан ваш сервер по умолчанию (обратите внимание, что здесь кавычки не требуются). Для большинства сетей этого достаточно, и никаких других настроек не требуется (если вам не нужен прокси). Также ваш сервер по умолчанию используется всякий раз, когда конкретный сервер не предоставляется.

Кроме того, если вы используете POP-сервер (для входящей электронной почты), отличный от вашего SMTP-сервера (для исходящей электронной почты), вы также можете указать это:

set-net [
    user@domain.dom
    mail.server.dom
    pop.server.dom
]

Однако, если у вас одинаковые SMTP и POP-серверы, в этом нет необходимости.

3.2 Настройки прокси

Если вы используете прокси или брандмауэр, вы можете предоставить функцию set-net с настройками вашего прокси. Это может включать имя или адрес прокси-сервера, номер порта прокси для доступа к серверу и необязательный тип прокси. Например:

set-net [
    email@addr
    mail.example.com
    pop.example.com
    proxy.example.com
    1080
    socks
]

В этом примере будет использоваться прокси-сервер с именем proxy.example.com на его TCP-порту 1080 с методом прокси-сервера socks. Чтобы использовать прокси-сервер socks4, используйте слово socks4, а не socks. Чтобы использовать общий сервер CERN, используйте слово generic.

Вы также можете настроить прокси на разные машины для разных схем (протоколов). Каждый протокол имеет свой собственный прокси-объект, где вы можете установить значения прокси только для этой схемы. Вот пример настройки прокси для FTP:

system/schemes/ftp/proxy/host: "proxy2.example.com"

system/schemes/ftp/proxy/port-id: 1080

system/schemes/ftp/proxy/type: 'socks

В этом случае только FTP использует специальный прокси-сервер. Обратите внимание, что имя компьютера должно быть строкой, а тип прокси - буквальным словом.

Вот еще два примера. В первом примере прокси-сервер для HTTP устанавливается как общий (CERN) метод прокси-сервера:

system/schemes/http/proxy/host: "wp.example.com"

system/schemes/http/proxy/port-id: 8080

system/schemes/http/proxy/type: 'generic

В приведенном выше примере все HTTP-запросы проходят через общий прокси-сервер на wp.example.com с использованием TCP-порта 8080.

Если вы хотите отключить настройки прокси для определенной схемы, вы можете установить для полей прокси значение false.

system/schemes/smtp/proxy/host: false

system/schemes/smtp/proxy/port-id: false

system/schemes/smtp/proxy/type: false

В приведенном выше примере вся исходящая электронная почта не проходит через прокси. Значение false предотвращает использование даже прокси по умолчанию. Если вы установите для этих полей значение none, то будет использоваться прокси по умолчанию, если он настроен.

Если вы хотите обойти настройки прокси-сервера для определенных машин, например, в вашей локальной сети, вы можете предоставить список обхода. Вот список обхода прокси по умолчанию:

system/schemes/default/proxy/bypass:
    ["host.example.net" "*.example.com"]

Обратите внимание, что для сопоставления с образцом можно использовать символы звездочки (*) и вопросительного знака (?). Звездочка (*), используемая в приведенном выше примере, позволяет обойти все машины, заканчивающиеся на example.com.

Чтобы установить список обхода только для схемы HTTP, введите:

system/schemes/http/proxy/bypass:
    ["host.example.net" "*.example.com"]

3.3 Другие настройки

Помимо настроек прокси, вы можете установить значения тайм-аута сети для всех схем (по умолчанию) или для определенных схем. Например, чтобы увеличить время ожидания для всех схем, вы можете написать:

system/schemes/default/timeout: 0:05

Это устанавливает тайм-аут сети на 5 минут.

Если вы хотите увеличить тайм-аут только для SMTP, вы должны написать:

system/schemes/smtp/timeout: 0:10

В некоторых схемах (schemes) есть настраиваемые поля. Например, схема FTP позволяет установить пассивный режим для всех передач:

system/schemes/ftp/passive: on

Пассивный режим FTP полезен, потому что FTP-серверы, которые установлены в пассивный режим, не пытаются подключиться обратно через ваш брандмауэр.

При выполнении HTTP-доступа к веб-сайтам вы можете захотеть использовать другое поле user-agent в HTTP-запросе, чтобы получить лучшие результаты на нескольких сайтах, которые определяют тип браузера:

system/schemes/http/user-agent: "Mozilla/4.0"

3.4 Доступ к настройкам

Каждый раз, когда REBOL запускается, он читает файл user.r, чтобы найти сетевые настройки. Эти настройки выполняются с помощью функции set-net. Скрипты имеют доступ к этим настройкам через объект system/schemes.

system/user/email ; used for email from and reply
system/schemes/default/host - your primary server
system/schemes/pop/host - your POP server
system/schemes/default/proxy/host - proxy server
system/schemes/default/proxy/port-id - proxy port
system/schemes/default/proxy/type - proxy type

Ниже приведена функция, которая возвращает блок, содержащий настройки сети, в том же порядке, в котором их принимает set-net:\\

get-net: func [][
    reduce [
        system/user/email
        system/schemes/default/host
        system/schemes/pop/host
        system/schemes/default/proxy/host
        system/schemes/default/proxy/port-id
        system/schemes/default/proxy/type
    ]
]

probe get-net

4. DNS - служба доменных имен (Domain Name Service)

DNS - это сетевая служба, которая переводит доменные имена в связанные с ними IP-адреса. Кроме того, вы можете использовать DNS для поиска машины и доменного имени по IP-адресу.

Протокол DNS можно использовать тремя способами: вы можете найти первичный IP-адрес в имени машины, вы можете найти в доменном имени IP-адрес и вы можете найти имя и IP-адрес вашей локальной системы.

Чтобы найти основной IP-адрес определенного компьютера в определенном домене, введите:

print read dns://www.rebol.com
207.69.132.8

Вы также можете получить доменное имя, связанное с определенным IP-адресом:

print read dns://207.69.132.8
rebol.com

Обратите внимание, что этот обратный поиск DNS нередко возвращает значение «none». Есть машины, у которых нет имен хостов.

print read dns://11.22.33.44
none

Чтобы узнать имя хоста вашей системы, прочтите пустой URL-адрес DNS в форме:

print read dns://
crackerjack

Возвращаемые здесь данные зависят от типа машины. Это может быть неполное имя хоста, как показано выше, но также может быть полное имя хоста, crackerjack.example.com. Это зависит от операционной системы и конфигурации сети в операционной системе.

Вот пример, который ищет и распечатывает IP-адреса для ряда веб-сайтов:

domains: [
    www.rebol.com
    www.rebol.org
    www.mochinet.com
    www.sirius.com
]

foreach domain domains [
    print ["address for" domain "is:"
        read join dns:// domain]
]
address for www.rebol.com is: 207.69.132.8
address for www.rebol.org is: 207.66.107.61
address for www.mochinet.com is: 216.127.92.70
address for www.sirius.com is: 205.134.224.1

5. Протокол Whois

Протокол whois получает информацию о доменных именах из центрального реестра. Сервис whois предоставляется организациями, работающими в Интернете. Whois часто используется для получения регистрационной информации о домене или сервере в Интернете. Он может сказать вам, кто владеет доменом, как можно связаться с их техническим контактом, а также другую информацию.

Для получения информации используйте функцию read (чтение) с URL-адресом whois. Этот URL-адрес должен содержать имя домена и имя сервера Whois, разделенные знаком (@). Например, чтобы получить информацию о example.com из реестра Internic:

print read whois://example.com@rs.internic.net
connecting to: rs.internic.net
Whois Server Version 1.1
Domain names in the .com, .net, and .org domains can now be
registered with many different competing registrars. Go to
http://www.internic.net for detailed information.
Domain Name: EXAMPLE.COM
Registrar: NETWORK SOLUTIONS, INC.
Whois Server: whois.networksolutions.com
Referral URL: www.networksolutions.com
Name Server: NS.ISI.EDU
Name Server: VENERA.ISI.EDU
Updated Date: 17-aug-1999
>>> Last update of whois database: Sun, 16 Jul 00 03:16:34 EDT <<<
The Registry database contains ONLY .COM, .NET, .ORG, .EDU domains
and Registrars.

Приведенный выше код является только примером. Детали возвращаемой информации и серверов, поддерживающих whois, со временем меняются.

Если вместо имени домена вы укажете слово, будут возвращены все записи, соответствующие этому слову:

print read whois://example@rs.internic.net
connecting to: rs.internic.net
Whois Server Version 1.1
Domain names in the .com, .net, and .org domains can now be
registered with many different competing registrars. Go to
http://www.internic.net for detailed information.
EXAMPLE.512BIT.ORG
EXAMPLE.ORG
EXAMPLE.NET
EXAMPLE.EDU
EXAMPLE.COM
To single out one record, look it up with "xxx", where xxx is one
of the of the records displayed above. If the records are the same, look them
up with "=xxx" to receive a full display for each record.
>>> Last update of whois database: Sun, 16 Jul 00 03:16:34 EDT <<<
The Registry database contains ONLY .COM, .NET, .ORG, .EDU domains
and Registrars.

Протокол whois не принимает URL-адреса, такие как www.example.com, если только URL-адрес не является частью названия компании регистранта.

6. Протокол Finger

Протокол finger извлекает информацию о пользователе, хранящуюся в файле журнала пользователя.

Чтобы запросить информацию о пользователе с сервера, он должен работать по протоколу finger. Информация запрашивается путем чтения пальца (finger) URL-адреса, который содержит имя пользователя и имя домена в формате стиля электронной почты:

print read finger://username@example.com

В приведенном выше примере извлекается информация о пользователе по адресу username@example.com. Возвращаемая информация зависит от информации, предоставленной пользователем, и настроек сервера finger. Кроме того, детали возвращаемой информации зависят от каждого сервера; приведенные ниже примеры описывают только типичные серверы. Многие серверы могут вести себя нестандартно на своих цифровых портах.

Например, может быть возвращена следующая информация:

Login: username
Name: Firstname Lastname
Directory: /home/user
Shell: /usr/local/bin/tcsh
Office: City, State +1 555 555 5555
Last login Wed Jul 28 01:10 (PDT) on ttyp0 from some.example.com
No Mail.
No Plan.

Обратите внимание, что finger сообщает, когда пользователь в последний раз входил в систему с машины и есть ли у пользователя ожидающая почта. Если пользователь читает электронную почту из этой учетной записи, finger иногда сообщает, когда почта была получена и когда пользователь в последний раз получал ее:

New mail received Sun Sep 26 11:39 1999 (PDT)
Unread since Tue Sep 21 04:45 1999 (PDT)

Сервер finger может также сообщать о содержимом файла plan (план) и файла project (проект), если они существуют. Пользователи могут включать любую информацию в файл плана или проекта.

Также возможно получить информацию о пользователях, используя их настоящее имя или фамилию. Некоторые серверы finger требуют, чтобы вы использовали заглавные буквы в именах точно так, как они отображаются в файле входа или в файле, используемом онлайн-сервером finger, для получения информации о пользователе. Другие finger-серверы более либеральны в отношении капитализации. Сервер finger будет отвечать на запросы настоящего имени, возвращая все списки, соответствующие критериям запроса. Например, если на хосте несколько пользователей с именем zaphod, то ввод запроса

print read finger://Zaphod@main.example.com

будет извлекать всех таких пользователей, чье имя или фамилия Zaphod.

Некоторые серверы finger возвращают список пользователей, если имя пользователя опущено. Например,

print read finger://main.example.com

получает список всех пользователей, вошедших в систему, если это позволяет служба finger, установленная на хост-машине.

Некоторые хост-машины ограничивают сервисы finger по соображениям безопасности. Они могут потребовать действительное имя пользователя и вернуть только информацию об этом пользователе. Если вы укажете такой сервер без предоставления информации о пользователе, сервер сообщит, что ему требуется конкретная информация о пользователе.

If a system does not support the finger protocol, REBOL reports an access error:

print read finger://host.dom
connecting to: host.dom
Access Error: Cannot connect to host.dom.
Where: print read finger://host.dom

7. Daytime - протокол сетевого времени.

Дневной протокол извлекает текущий день и время. Чтобы подключиться к дневному серверу, используйте read (чтение) с URL. URL-адрес содержит имя сервера, с которого следует читать дату:

print read daytime://everest.cclabs.missouri.edu
Fri Jun 30 16:40:46 2000

Формат информации, возвращаемой серверами, может различаться в зависимости от сервера. Обратите внимание, что часовой пояс может отсутствовать.

Если выбранный вами сервер не поддерживает дневное время, REBOL возвращает ошибку:

print read daytime://www.example.com
connecting to: www.example.com
** Access Error: Cannot connect to www.example.com.
** Where: print read daytime://www.example.com

8. HTTP - протокол передачи гипертекста (Hyper Text Transfer Protocol)

Всемирная паутина управляется двумя фундаментальными технологиями: HTTP и HTML. HTTP - это протокол передачи гипертекста, который контролирует, как веб-серверы и веб-браузеры взаимодействуют друг с другом. HTML - это язык гипертекстовой разметки, который определяет структуру и содержимое веб-страницы.

Чтобы получить веб-страницу, браузер отправляет запрос на веб-сервер по протоколу HTTP. При получении запроса сервер интерпретирует его, иногда используя сценарий CGI (см. CGI - Общий интерфейс шлюза), и отправляет данные обратно. Эти данные могут быть чем угодно, включая HTML, текст, изображения, программы и звук.

8.1 Чтение веб-страницы

Чтобы прочитать веб-страницу, используйте функцию read (чтение) с URL-адресом HTTP. Например:

page: read http://www.rebol.com

Это вернет веб-страницу www.rebol.com. Обратите внимание, что при чтении возвращается строка, содержащая HTML-код страницы. Никакая графика или другая информация не загружаются. Для этого вам нужно будет предоставить дополнительные чтения. Страница может отображаться как HTML-код с помощью print, ее можно записать в файл с помощью write или отправить по электронной почте с помощью send.

print page

write %index.html page

send zaphod@example.com page

Страницу можно обрабатывать различными способами с помощью различных функций REBOL, таких как parse (синтаксический анализ), find (поиск) и load (загрузка).

Например, чтобы найти на веб-странице все вхождения слова REBOL, вы можете написать:

parse read http://www.rebol.com [
    any [to "REBOL" copy line to newline (print line)]
]

8.2 Скрипты на веб-сайтах

Веб-сервер может предоставлять больше, чем просто сценарии HTML. Веб-серверы также весьма полезны для предоставления сценариев REBOL.

Вы можете загружать сценарии REBOL прямо с веб-сервера с помощью load:

data: load http://www.rebol.com/data.r

Вы также можете оценивать скрипты прямо с сервера с помощью do:

data: do http://www.rebol.com/code.r

Предупреждение

Делайте это осторожно. Оценка произвольных сценариев на открытых серверах Интернета вызывает проблемы. Оценивайте сценарий только в том случае, если вы полностью доверяете его источнику, полностью проверили его источник или установили максимальные параметры безопасности REBOL.

Кроме того, веб-страницы, содержащие HTML, могут содержать встроенные сценарии REBOL, и их можно запускать с помощью:

data: do http://www.rebol.com/example.html

Чтобы определить, существует ли сценарий на странице перед его оценкой, используйте функцию script? (сценарий?).

if page: script? http://www.rebol.com [do page]

функция script? читает страницу с веб-сайта и возвращает страницу в позиции заголовка REBOL.

8.3 Загрузка страниц разметки

Страницы HTML и XML можно быстро преобразовать в блок REBOL с помощью функции load/markup (загрузки/разметки). Эта функция возвращает блок, состоящий из всех тегов и строк, найденных на странице. Все интервалы и разрывы строк остаются без изменений.

Чтобы отфильтровать все теги веб-страницы и просто распечатать её текст, введите:

tag-text: load/markup http://www.rebol.com
text: make string! 2000

foreach item tag-text [
    if string? item [append text item]
]

print text

Затем вы можете искать в этом тексте строковые шаблоны. Он будет содержать все пробелы и разрывы строк исходного HTML-файла.

Вот еще один пример, который проверяет все ссылки, найденные на веб-странице, чтобы убедиться, что страницы, на которые они ссылаются, существуют:

REBOL []

page: http://www.rebol.com/developer.html
set [path target] split-path page
system/options/quiet: true  ; turn off connection msgs
tag-text: load/markup page
links: make block! 100

foreach tag tag-text [  ; find all anchor href tags
    if tag? tag [
        if parse tag [
            "A" thru "HREF="
            [{"} copy link to {"} | copy link to ">"]
            to end
        ][
            append links link
        ]
    ]
]

print links

foreach link unique links [  ; try each link
    if all [
        link/1 <> #"#"
        any [flag: not find link ":"
             find/match link "http:"]
    ][
        link: either flag [path/:link][to-url link]
        prin [link "... "]
        print either error? try [read link]
            ["failed"]["OK"]
    ]
]

8.4 Другие функции

Чтобы проверить, существует ли веб-страница, используйте команду exists?, которая возвращает истину (true), если страница существует.

if exists? http://www.rebol.com [
    print "page still there"
]

Примечание. Во многих случаях обычно быстрее просто прочитать страницу, чем сначала проверить, существует ли она. В противном случае сценарий должен дважды связаться с сервером, что может занять много времени.

Чтобы запросить дату последнего изменения веб-страницы, используйте функция modified? (измененный?):

print modified? http://www.rebol.com/developer.html

Однако обратите внимание, что не все веб-серверы предоставляют информацию о дате изменения. Динамически генерируемые веб-страницы обычно не возвращают дату изменения.

Еще один способ определить, изменилась ли веб-страница, - это время от времени опрашивать ее и проверять. Удобный способ проверить, что веб-страница изменилась, - использовать функцию checksum (контрольная сумма). Если ранее вычисленная контрольная сумма веб-страницы отличается от ее текущего значения, значит, веб-страница была изменена с момента последней проверки. Вот пример, в котором используется эта техника. Он проверяет страницу каждые восемь часов.

forever [
    page: read http://www.rebol.com
    page-sum: checksum page
    if any [
        not exists? %page-sum
        page-sum <> (load %page-sum)
    ][
        print ["Page changed" now]
        save %page-sum page-sum
        send luke@rebol.com page
    ]
    wait 8:00
]

Каждый раз, когда страница изменяется, она отправляется Люку по электронной почте.

8.5 Действовать как браузер

Обычно REBOL идентифицирует себя для сервера при чтении с веб-сайта. Однако некоторые серверы запрограммированы так, чтобы отвечать только определенным браузерам. Если запрос к серверу не создает правильную веб-страницу, вы можете изменить запрос, чтобы он выглядел так, как будто он поступил из какого-либо другого типа веб-браузера. Многие программы притворяются веб-браузером, чтобы заставить веб-сайты правильно реагировать. Однако эта практика в конечном итоге сводит на нет цель идентификации браузера.

Чтобы изменить HTTP-запросы так, чтобы они выглядели так, как будто они отправляются Netscape 4.0, вы можете изменить пользовательский агент в обработчике HTTP:

system/options/http/user-agent: "Mozilla/4.0"

Установка этой переменной влияет на все последующие HTTP-запросы.

8.6 Отправка запросов CGI

Запросы HTTP CGI могут быть отправлены двумя способами. Вы можете включить данные запроса CGI в URL-адрес или предоставить данные запроса с помощью операции HTTP post.

В запросе URL CGI используется обычный URL. Пример ниже отправляет сценарию CGI test.r значение 10 переменной data.

read http://www.example.com/cgi-bin/test.r?data=10

Пост-запрос CGI требует, чтобы вы предоставили данные CGI как часть уточнения /custom функции чтения read. В приведенном ниже примере показано, как данные отправляются в CGI:

read/custom http://www.example.com/cgi-bin/test.r [
    post "data: 10"
]

В этом примере уточнение /custom используется для предоставления дополнительной информации для чтения. Второй аргумент - это блок, который начинается со слова post, за которым следует строка для отправки.

Метод post полезен для простой отправки кода и данных REBOL на веб-сервер, на котором работает CGI. Следующий пример иллюстрирует это:

data: [sell 10 shares of "ACME" at $123.45]

read/custom http://www.example.com/cgi-bin/test.r reduce [
    `post mold data
]

Функция mold создаст правильную строку REBOL, которая будет отправлена ​​на сервер.

9. SMTP - простой протокол передачи почты (Simple Mail Transport Protocol)

Простой протокол передачи почты (SMTP) контролирует передачу сообщений электронной почты в Интернете. SMTP определяет взаимодействие между интернет-узлами, которые участвуют в пересылке электронной почты от отправителя к месту назначения.

9.1 Отправка электронной почты

Электронная почта отправляется через SMTP с использованием функции send (отправка). Эта функция может отправить сообщение электронной почты на один или несколько адресов электронной почты.

Для правильной работы send необходимо настроить вашу сеть. Функция отправки send требует, чтобы вы указали свой адрес электронной почты От и почтовый сервер по умолчанию. См. Раздел «Начальна выше.

Функция отправки send принимает два аргумента: адрес электронной почты и сообщение. Например:

send user@example.com "Hi from REBOL"

Первый аргумент должен быть типом данных электронной почты или блока. Второй аргумент может быть любым типом данных.

send luke@rebol.com $1000.00

send luke@rebol.com 10:30:40

send luke@rebol.com bill@ms.dom

send luke@rebol.com [Today 9-Apr-99 10:30]

Каждое из этих простых сообщений электронной почты можно интерпретировать на стороне получателя (с помощью REBOL) или просмотреть с помощью обычной программы электронной почты.

Вы можете отправить файл целиком, прочитав файл и передав его в качестве второго аргумента функции отправки:

send luke@rebol.com read %task.txt

Двоичные данные, такие как изображение или исполняемый файл, также могут быть отправлены:

send luke@rebol.com read/binary %rebol

Двоичные данные закодированы, чтобы их можно было передавать в виде текста.

Чтобы отправить самораспаковывающееся двоичное сообщение, вы можете написать:

send luke@rebol.com join "REBOL for the job" [
    newline "REBOL []" newline
    "write/binary %rebol decompress "
    compress read/binary %rebol
]

Когда сообщение получено, файл можно извлечь с помощью функции do.

9.2 Несколько получателей

Для отправки нескольким получателям вы можете указать блок имен электронной почты:

send [luke@rebol.com ben@example.com] message

В этом случае каждое сообщение адресуется индивидуально, а в поле "Кому" (To) отображается только имя получателя (аналогично адресации BCC).

Блок адресов электронной почты может быть любого размера или даже быть загруженным вами файлом. Просто убедитесь, что это действительные адреса, а не строки. Строки игнорируются.

friends: [
    bob@cnn.dom
    betty@cnet.dom
    kirby@hooya.dom
    belle@apple.dom
    ...
]

send friends read %newsletter.txt

9.3 Массовая рассылка

Если вы отправляете электронную почту большой группе, вы можете снизить нагрузку на свой сервер, доставив всем в группе одно сообщение. Это цель уточнения /only. Он использует функцию SMTP для отправки только одного сообщения на несколько адресов электронной почты. Используя список друзей из предыдущего примера:

send/only friends message

Сообщения не адресуются индивидуально. Возможно, вы видели этот режим в некоторых массовых рассылках, которые вы получаете. Когда вы получаете массовую рассылку писем, ваш адрес не отображается в поле To (Кому).

Режим массовой рассылки SMTP следует использовать для списков рассылки, а не для рассылки спама. Электронная почта со спамом не является надлежащим сетевым этикетом, в некоторых странах и штатах она является незаконной, а спам приведет к блокировке вашего интернет-провайдера и других сайтов.

9.4 Тема и заголовки

По умолчанию функция send использует первую строку сообщения в качестве темы. Чтобы указать собственную строку темы, вам необходимо указать заголовок электронной почты для функции send. В дополнение к теме вы можете указать организацию, дату и даже свои собственные настраиваемые поля.

Чтобы включить заголовок, используйте уточнение /header функции send и включите объект заголовка. Объект заголовка должен быть создан из объекта system/standard/email. Например:

header: make system/standard/email [
    Subject: "Seen REBOL yet?"
    Organization: "Freedom Fighters"
]

Обратите внимание, что стандартные поля, такие как адрес From (От), не являются обязательными и автоматически предоставляются функцией send.

Затем заголовок предоставляется в качестве аргумента для send/header:

send/header friends message header

Электронное письмо выше отправляется с использованием настраиваемого заголовка для каждого сообщения.

9.5 Отладка ваших скриптов

При тестировании сценариев электронной почты рекомендуется сначала отправить электронное письмо самому себе, прежде чем отправлять его другим. Внимательно изучите тестовое электронное письмо, чтобы убедиться, что оно именно то, что вам нужно. Часто возникают такие ошибки, как отправка имени файла, а не его содержимого. Например, вы можете написать:

send person %the-data-file.txt

Это отправляет имя файла, а не сам файл.

10. POP - протокол почтового отделения (Post Office Protocol)

Протокол почтового отделения (POP) позволяет получать электронную почту, ожидающую в почтовом ящике почтового сервера. POP определяет ряд операций для доступа и хранения электронной почты на вашем сервере.

10.1 Чтение электронной почты

Вы можете прочитать всю свою электронную почту в одной строке, не удаляя ее с почтового сервера: это делается путем чтения из URL-адреса POP, в котором вы указали свое имя пользователя, пароль и адрес электронной почты.

mail: read pop://user:pass@mail.example.com

Сообщения возвращаются в виде блока строк, который вы можете обрабатывать по одному сообщению за раз, используя такой код, как:

foreach message mail [print message]

Чтобы читать отдельные сообщения электронной почты с сервера, вам необходимо открыть соединение порта с сервером и обрабатывать каждое сообщение по одному. Чтобы открыть порт POP:

mailbox: open pop://user:pass@mail.example.com

В этом примере доступ к mailbox (почтовому ящику) можно получить как серию. Он отвечает на многие стандартные функции серии, такие как length? (длина?), first (первый), second (второй), third (третий), pick (выбрать), next (следующий), back (назад), head (голова), tail (хвост), head? (голова?) , tail? (хвост?), remove (удалить) и clear (очистить).

Чтобы определить количество почтовых сообщений, находящихся на сервере, используйте length? (длина?) функция.

print length? mailbox
37

Кроме того, вы можете узнать общий размер всех сообщений и отдельные размеры сообщений с помощью:

print mailbox/locals/total-size

print mailbox/locals/sizes

Чтобы отобразить первое, второе и последнее сообщение, вы можете написать:

print first mailbox

print second mailbox

print last mailbox

Вы также можете использовать pick, чтобы получить конкретное сообщение:

print pick mailbox 27

Вы можете получать и отображать каждое сообщение от самого старого до самого нового, используя цикл, идентичный тому, который используется для других типов серий:

while [not tail? mailbox] [
    print first mailbox
    mailbox: next mailbox
]

Вы также можете читать свою электронную почту от самой новой до самой старой с помощью цикла, например:

mailbox: tail mailbox

while [not head? mailbox] [
    mailbox: back mailbox
    print first mailbox
]

Когда вы закончите, не забудьте закрыть (close) почтовый ящик (mailbox). Это можно сделать с помощью такой строки, как:

close mailbox

10.2 Удаление электронной почты

Как и в случае с сериями, функцию remove (удаления) можно использовать для удаления одного сообщения, а функцию clear (очистка) можно использовать для удаления всех сообщений от текущей позиции до конца почтового ящика.

Например, чтобы прочитать сообщение, сохранить его в файл и удалить с сервера:

mailbox: open pop://user:pass@mail.example.com
write %mail.txt first mailbox
remove mailbox
close mailbox

Сообщение удаляется с сервера после закрытия (close).

Чтобы удалить 22-е сообщение электронной почты с сервера, вы можете написать:

user:pass@mail.example.com
remove at mailbox 22
close mailbox

Вы можете удалить ряд сообщений, используя уточнение /part с функцией удаления (remove):

remove/part mailbox 5

Чтобы удалить все сообщения в почтовом ящике, используйте функцию clear (очистка):

mailbox: open pop://user:pass@example.com
clear mailbox
close mailbox

функция clear также может быть использована в различных позициях в почтовом ящике, чтобы удалить сообщения в конце почтового ящика.